home *** CD-ROM | disk | FTP | other *** search
/ Atari Mega Archive 1 / Atari Mega Archive - Volume 1.iso / language / gemfsc18.lzh / AESSRC18.LZH / AESUTIL.S / RCINTERS.S < prev    next >
Text File  |  1992-03-07  |  3KB  |  55 lines
  1. ;*************************************************************************
  2. ;* RCINTERS.S - Calc intersection of two GRECT rectangles.
  3. ;*************************************************************************
  4.  
  5. _rc_intersect::
  6.           move.l    4(sp),a1 
  7.           move.l    8(sp),a0 
  8.           movem.l   d3-d4,-(sp)
  9.                                         ; Calc right-side x...
  10.           move.w    (a1),d0             ;  rx1 = x1 + w1 
  11.           add.w     4(a1),d0            
  12.           move.w    (a0),d1             ;  rx2 = x2 + w2
  13.           add.w     4(a0),d1            
  14.           cmp.w     d0,d1               ;  compare rx1 <-> rx2
  15.           blt.s     .gotrx              ;  proper rx is the smaller
  16.           move.w    d0,d1               ;  of the two.
  17. .gotrx:   
  18.                                         ; Calc bottom y...
  19.           move.w    2(a1),d0            ;  by1 = y1 + h1
  20.           add.w     6(a1),d0            
  21.           move.w    2(a0),d2            ;  by2 = y2 + h2
  22.           add.w     6(a0),d2            
  23.           cmp.w     d0,d2               ;  compare by1 <-> by2
  24.           blt.s     .gotby              ;  proper by is the smaller
  25.           move.w    d0,d2               ;  of the two.       
  26. .gotby:                                 
  27.                                         ; Calc left-side x...
  28.           move.w    (a0),d3             ;  assume x2
  29.           cmp.w     (a1),d3             ;  compare x1 <-> x2  
  30.           bge.s     .gotlx              ;  proper lx is larger
  31.           move.w    (a1),d3             ;  of the two.
  32. .gotlx:                                 
  33.                                         ; Calc top y...
  34.           move.w    2(a0),d4            ;  assume y2
  35.           cmp.w     2(a1),d4            ;  compare y1 <-> y2 
  36.           bge.s     .gotty              ;  proper ty is larger
  37.           move.w    2(a1),d4            ;  of the two.
  38. .gotty:
  39.                                         ; Got all the x/y's...
  40.           moveq.l   #0,d0               ; Assume intersection is false.             
  41.           move.w    d3,(a0)+            ; store left x
  42.           move.w    d4,(a0)+            ; store top y
  43.           sub.w     d3,d1               ; compute width
  44.           ble.s     .done               ; if negative or zero, no intersect
  45.           move.w    d1,(a0)+            ; else store it
  46.           sub.w     d4,d2               ; compute height
  47.           ble.s     .done               ; if negative or zero, no intersect
  48.           move.w    d2,(a0)+            ; else store it
  49.           moveq.l   #1,d0               ; intersection is true 
  50. .done:
  51.           movem.l   (sp)+,d3-d4
  52.           tst.w     d0                  ; insure CCR return matches d0.
  53.           rts
  54.  
  55.